Concrete syntax of the Unify connector construct
------------------------------------------------

The concrete syntax of the Unify connector construct is specified in Backus-Naur
form below.  This syntax has been elaborated into an ANTLR specification, which
is used by the Unify implementation as the basis of its connector parser, and
can be downloaded directly from our Subversion repository at
http://soft.vub.ac.be/svn-gen/unify/src/org/unify_framework/abstract_syntax/connector_mechanism/parser/Connector.g.

<connector> ::= <external-connector>
              | <internal-connector>

<external-connector> ::= <before-connector>
                       | <after-connector>
                       | <replace-connector>
                       | <around-connector>
                       | <parallel-connector>
                       | <alternative-connector>
                       | <iterating-connector>

<internal-connector> ::= <synchronizing-connector>
                       | <switching-connector>

<before-connector> ::= "CONNECT" <activity>
                       "BEFORE" <pointcut>
                       ("" | "IF" <condition>)

<after-connector> ::= "CONNECT" <activity>
                      "AFTER" <pointcut>
                      ("" | "IF" <condition>)

<replace-connector> ::= "CONNECT" <activity>
                        "INSTEAD OF" <pointcut>

<around-connector> ::= "CONNECT" <activity>
                       "AROUND" <pointcut>
                       ("" | "IF" <condition>)
                       ("" | "PROCEEDING AT" <pointcut>)

<parallel-connector> ::= "CONNECT" <activity>
                         "PARALLEL TO" <pointcut>
                         ("" | "IF" <condition>)

<alternative-connector> ::= "CONNECT" <activity>
                            "ALTERNATIVE TO" <pointcut>
                            "IF" <condition>

<iterating-connector> ::= "CONNECT" <activity>
                          "ITERATING OVER" <pointcut>
                          "UNTIL" <condition>

<synchronizing-connector> ::= "CONNECT" <activity>
                              "IN" <pointcut>
                              "AND-SPLITTING AT" <pointcut>
                              "SYNCHRONIZING AT" <pointcut>

<switching-connector> ::= "CONNECT" <activity>
                          "IN" <pointcut>
                          "SWITCHING AT" <pointcut>
                          "IF" <condition>
                          "XOR-JOINING AT" <pointcut>